/**
 * @author eidiot
 */
class Album {
	//显示图片的mc
	private var holder:MovieClip;
	//向前显示按钮
	private var prev:MovieClip;
	//向后显示按钮
	private var next:MovieClip;
	//图片数组
	private var picArr:Array;
	//当前图片索引
	private var index:Number;
	//Album类的实例
	private static var album:Album;	
	//构造函数
	public function Album() {
		//初始化图片数组
		picArr=["pic1.jpg", "pic2.jpg", "pic3.jpg"];
		//初始化mc
		holder=_root.createEmptyMovieClip ("holder_mc", 1);
		prev=_root.createEmptyMovieClip ("prev", 2);
		next=_root.createEmptyMovieClip ("next", 3);
		//显示第一张图片
		showPhotoAt(0);
		//载入按钮
		loadBtns();
	}
	private function showPhotoAt(n:Number):Void {
		//图片总数
	    var lastIndex:Number = picArr.length - 1;
	    //如果n超过图片总数则显示第一张图片
	    if (n > lastIndex) n = 0;
	    //如果n小于0则显示最后一张图片
	    else if (n < 0) n = lastIndex;
	    //设置当前索引值
	    index=n;
	    //显示图片
	    holder.loadMovie (picArr[index]);
	};
	private function loadBtns():Void{
		//载入按钮图片并设置位置
		prev.loadMovie("prev.jpg");
		next.loadMovie("next.jpg");
		prev._x=450;
		prev._y=350;
		next._x=480;
		next._y=350;
		//用变量owner指向this
		var owner:Object=this;
		//用_root的onEnterFrame检测图片是否已经载入
		//载入后设置onRelease函数
		_root.onEnterFrame=function(){
			if(owner.prev._width&&owner.next._width){
				owner.prev.onRelease=function(){
					//载入前1张图片
					owner.showPhotoAt (owner.index - 1);	
				};
				owner.next.onRelease=function(){
					//载入后一张图片
					owner.showPhotoAt (owner.index + 1);	
				};
				//删除onEnterFrame事件
				delete _root.onEnterFrame;
			}			
		};
	}
	//为MTASC编译swf建立一个main函数
	public static function main() : Void {
		album=new Album();
	}
}